函数参考


GUICtrlCreateDate

在GUI上创建一个日期控件.

GUICtrlCreateDate ( "文本", 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

文本 预选的日期.(总是为 "yyyy/mm/dd" 格式).
左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(-1):$DTS_LONGDATEFORMAT
强制性样式: $WS_TABSTOP
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表.
默认值(default) (-1) : WS_EX_CLIENTEDGE

返回值

成功: 返回新控件的控件标识符(控件ID).
失败: 返回值为 0.

注意/说明

若要获得控件的各种值,请参考 GUICtrlRead.
要设置或者修改控件信息,请参考 GUICtrlUpdate....

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_DATE, 新样式,...).

要格式化 日期/时间 请查看例子3来了解怎么使用GuiCtrlSendMsg 和 $DTM_SETFORMAT.

要使用上方指定的值,您必须包含 #include <DateTimeConstants.au3> 在你的脚本中.

默认大小为: $GUI_DOCKHEIGHT.

相关

GUICoordMode (Option), GUICtrlSetState, GUIGetMsg, GUICtrlRead

示例/演示


#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>

Example1()
Example2()
Example3()
Example4()

; 示例1
Func Example1()
    Local $date, $msg

    GUICreate("My GUI get date", 200, 200, 800, 200)
    $date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
    GUISetState()

    ; 运行界面,直到窗口被关闭
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(4096, "Date", GUICtrlRead($date))
    GUIDelete()
EndFunc   ;==>Example1

; 示例2
Func Example2()
    Local $n, $msg

    GUICreate("My GUI get date", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 10, 10, 100, 20, $DTS_SHORTDATEFORMAT)
    GUISetState()

    ; 运行界面,直到窗口被关闭
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(0, "Date", GUICtrlRead($n))
    GUIDelete()
EndFunc   ;==>Example2

; 示例3
Func Example3()
    Local $date, $DTM_SETFORMAT_, $style

    GUICreate("My GUI get date", 200, 200, 800, 200)
    $date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)

    ; 设置默认格式(注意帮助上的说明)
    $DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
    $style = "yyyy/MM/dd HH:mm:ss"
    GUICtrlSendMsg($date, $DTM_SETFORMAT_, 0, $style)

    GUISetState()
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    MsgBox(4096, "Time", GUICtrlRead($date))
EndFunc   ;==>Example3

; 示例4
Func Example4()
    Local $n, $msg

    GUICreate("My GUI get time", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState()

    ; 运行界面,直到窗口被关闭
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(4096, "Time", GUICtrlRead($n))
    GUIDelete()
EndFunc   ;==>Example4