函数参考


GUISetCursor

设置(鼠标经过窗口时的)鼠标指针.

GUISetCursor ( [指针ID [, 覆盖 [, 窗口句柄]]] )

参数

指针ID [可选参数] 鼠标指针 Id (请查看下面的注意部分).
覆盖 [可选参数] 当鼠标经过控件时强制切换鼠标指针(请看下面的解释).
0 = (默认)不覆盖控件本身设置的默认指针.
1= 忽略控件本身设置的默认指针而强制性使用给定指针.
窗口句柄 [可选参数] 窗口句柄,可由 GUICreate 的返回值获得(默认使用上一次用过的句柄).

返回值

None.

注意/说明

若给定的 指针ID 无效则程序将使用标准的箭头指针代替.

通常当我们把鼠标指针移到一个编辑框或其它控件上时指针形状就会变化."覆盖"选项使得我们能保证在任何时候显示的都是给定的指针.注意:若曾使用 GUICtrlSetCursor 设置过某个控件的指针则在鼠标经过该控件时将以该指针为准.

详细的指针ID列表请查看 MouseGetCursor.
CursorId = 16 将隐藏鼠标光标.

相关

GUICtrlSetCursor

示例/演示


#include <GUIConstantsEx.au3>

Global $IDC = -1, $newIDC = 0

Example()

Func Example()

    HotKeySet("{Esc}", "Increment")

    GUICreate("Press Esc to Increment", 400, 400, 0, 0, 0x04CF0000, 0x00000110)

    GUISetState()

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
        If $newIDC <> $IDC Then
            $IDC = $newIDC
            GUISetCursor($IDC)
        EndIf
        ToolTip("GUI Cursor #" & $IDC)
    WEnd
EndFunc   ;==>Example

Func Increment()
    $newIDC = $IDC + 1
    If $newIDC > 15 Then $newIDC = 0
EndFunc   ;==>Increment