函数参考

_GDIPlus_GraphicsDrawClosedCurve

绘制封闭曲线

#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawClosedCurve($hGraphics, $aPoints[, $hPen = 0])

参数

$hGraphics 图形对象的句柄
$aPoints 指定曲线点的数组:
[0][0] - 点的数量
[1][0] - 第 1 点 X 位置
[1][1] - 第 1 点 Y 位置
[2][0] - 第 2 点 X 位置
[2][1] - 第 2 点 Y 位置
[n][0] - 第 n 点 X 位置
[n][1] - 第 n 点 Y 位置
$hPen [可选参数] 绘制封闭曲线的画笔句柄. 如果为 0,使用宽度为 1 的实心黑笔.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

在封闭基线中, 曲线绘制到数组内最后元素标识点且与数组中的首个元素标识点连接.
标示点位置的数组必须包含至少三个元素.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $aPoints[8][2]

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 描绘基数样条
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    $aPoints[0][0] = 7
    $aPoints[1][0] = 50
    $aPoints[1][1] = 50
    $aPoints[2][0] = 100
    $aPoints[2][1] = 25
    $aPoints[3][0] = 200
    $aPoints[3][1] = 5
    $aPoints[4][0] = 250
    $aPoints[4][1] = 50
    $aPoints[5][0] = 300
    $aPoints[5][1] = 100
    $aPoints[6][0] = 350
    $aPoints[6][1] = 200
    $aPoints[7][0] = 250
    $aPoints[7][1] = 250

    _GDIPlus_GraphicsDrawClosedCurve($hGraphic, $aPoints)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main