函数参考


_GDIPlus_ImageGetFlags

枚举图像的像素数据属性

#Include <GDIPlus.au3>
_GDIPlus_ImageGetFlags($hImage)

参数

$hImage 图像对象句柄

返回值

成功: 返回下格式数组:
[0] - 像素数据属性设置的标志
[1] - 由分隔符"|"分割的像素数据属性字符串
失败: 返回空数组设置@error, @extended 设置为错误的位置@error:
0 - 无错误.

注意/说明

 @error 4 依赖于 GDI+ UDF 返回的 -1 或 0, 而不是图像句柄错误.
 对于以 GdipGetImageFlags 常量设置的整数标记使用 BitAND.

相关

_GDIPlus_ImageGetPixelFormat

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>


Global $iMemo

_Main()

Func _Main()
    Local $hBitmap, $hImage, $aRet

    ; 创建 GUI
    GUICreate("GDI+", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 初始化 GDI+ 库
    _GDIPlus_Startup()

    ; 捕获到 32 位位图
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; 显示屏幕捕获的像素数据属性的枚举值
    $aRet = _GDIPlus_ImageGetFlags($hImage)
    $aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
    MemoWrite("Image pixel data attributes of screen capture: " & $aRet[1]);
    MemoWrite();
    MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]);
    MemoWrite();

    ; 保存屏幕捕获位图到文件
    _GDIPlus_ImageSaveToFile($hImage, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; 清理资源
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; 从文件中加载屏幕捕获位图
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; 显示已保存文件的像素数据属性的枚举值
    $aRet = _GDIPlus_ImageGetFlags($hImage)
    $aRet[1] = @CRLF & StringReplace($aRet[1], "|", @CRLF)
    MemoWrite("Image pixel data attributes of saved file: " & $aRet[1]);
    MemoWrite();
    MemoWrite("Image flag set of pixel data attributes: " & $aRet[0]);

    ; 清理资源
    _GDIPlus_ImageDispose($hImage)

    ; 关闭 GDI+ 库
    _GDIPlus_Shutdown()

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage = '')
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite