函数参考


_GDIPlus_ParamInit

初始化编码器的参数列表

#Include <GDIPlus.au3>
_GDIPlus_ParamInit($iCount)

参数

$iCount 列表将包含参数的总数

返回值

成功: 返回 $tagGDIPPENCODERPARAMS 结构
失败: 返回 0

注意/说明

为了将参数传递给编码器,您必须使用一个编码器参数列表.
该函数用于初始化一个编码器参数列表, 用以将添加的实际参数传递给 _GDIPlus_ParamAdd() 函数.

相关

_GDIPlus_ParamAdd, $tagGDIPPENCODERPARAMS

示例/演示


#include <GDIPlus.au3>
#include <ScreenCapture.au3>

_Main()

Func _Main()
    Local $hImage, $sCLSID, $tData, $tParams

    ; 捕获屏幕
    _ScreenCapture_Capture(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; 初始化 GDI+ 库
    _GDIPlus_Startup()

    ; 加载图像
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; 获取 JPEG 编码器的 CLSID
    $sCLSID = _GDIPlus_EncodersGetCLSID("JPG")

    ; 建立表示旋转 90 度的参数
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit(1)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; 保存旋转后的图像
    _GDIPlus_ImageSaveToFileEx($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; 关闭 GDI+ 库
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main