函数参考


_GUICtrlComboBox_AddDir

添加目录与文件的名称

#include <GuiComboBox.au3>
_GUICtrlComboBox_AddDir($hWnd, $sFile [, $iAttributes = 0 [, $fBrackets = True]])

参数

$hWnd 控件的控件ID/句柄
$sFile 指定一个绝对路径,相对路径,或文件名
$iAttributes [可选参数] 指定添加文件或目录的属性:
$DDL_READWRITE - 可读/写文件
$DDL_READONLY - 包括只读文件
$DDL_HIDDEN - 包括隐藏文件
$DDL_SYSTEM - 包括系统文件
$DDL_DIRECTORY - 包括子目录
$DDL_ARCHIVE - 包括存档文件
$DDL_DRIVES - 所有映射驱动器添加到列表
$DDL_EXCLUSIVE - 仅包括指定属性的文件
$fBrackets [可选参数] 当使用 $DDL_DRIVES 时指定是否包含括号

返回值

成功: 返回 最后添加项的 0 基索引
失败: 返回 -1

注意/说明

如果空间不够存储新字符串, 返回值为$CB_ERRSPACE
需要Constants.au3预定义常量

相关

_GUICtrlComboBox_InitStorage

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Add Dir", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main