函数参考


_GUICtrlComboBox_GetEditSel

获取组合框的编辑控件里当前选项开始和结束字符的位置

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetEditSel($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回如下格式的数组:
    [0] - 起始位置.
    [1] - 结束位置.
失败: 返回 -1

注意/说明

如果消息发送到具有 $CBS_DROPDOWN 或 $CBS_DROPDOWNLIST 样式的组合框, 该函数将失败.

相关

_GUICtrlComboBox_SetEditSel, _GUICtrlComboBoxEx_SetEditSel

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $aSel, $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Get Edit Sel", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Select Item
    _GUICtrlComboBox_SetCurSel($hCombo, 2)

    ; Set Edit Sel
    _GUICtrlComboBox_SetEditSel($hCombo, 0, 4)

    ; Get Edit Sel
    $aSel = _GUICtrlComboBox_GetEditSel($hCombo)
    MemoWrite(StringFormat("Edit Sel: %d - %d", $aSel[0], $aSel[1]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite