函数参考


_GUICtrlComboBox_InitStorage

分配用于存储列表框项目的内存

#include <GuiComboBox.au3>
_GUICtrlComboBox_InitStorage($hWnd, $iNum, $iBytes)

参数

$hWnd 控件的控件ID/句柄
$iNum 项目数量
$iBytes 内存分配字节数

返回值

成功: 返回预分配内存总数
失败: $CB_ERRSPACE

注意/说明

有助于加快组合控件具有大量(超过 100)项目时的初始化.

可以使用 $iNum 与 $iBytes 参数估计所需内存量.
如果你估计过高,会分配多余的额外内存.
如果你估计过低, 正常分配的内存将用于超过要求的项目数额.

相关

_GUICtrlComboBox_AddDir, _GUICtrlComboBox_AddString, _GUICtrlComboBox_InsertString

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Init Storage", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; Init Storaged
    MsgBox(4160, "信息", "Pre-Allocated Memory For: " & _GUICtrlComboBox_InitStorage($hCombo, 50, 500) & " items")

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main