函数参考

_GUICtrlComboBox_InsertString

插入字符串

#include <GuiComboBox.au3>
_GUICtrlComboBox_InsertString($hWnd, $sText [, $iIndex = -1])

参数

$hWnd 控件的控件ID/句柄
$sText 要插入的文本字符串
$iIndex [可选参数] 插入字符串位置的 0 基索引.

返回值

成功: 返回插入位置的 0 基索引
失败: 返回 -1

注意/说明

如果 $iIndex 参数为 -1,该字符串被添加到列表框的末尾.

如果组合控件已具有 $WS_HSCROLL 样式,且你插入字符串位置大于组合控件,
你应该使用 _GUICtrlComboBox_SetHorizontalExtent 函数确保控件出现水平滚动条.

相关

_GUICtrlComboBox_AddString, _GUICtrlComboBox_InitStorage

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Insert String", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 插入字符串
    _GUICtrlComboBox_InsertString($hCombo, "Some Inserted string", 0)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main