函数参考

_GUICtrlComboBox_SelectString

搜索组合框列表中以指定字符串开始的项目

#include <GuiComboBox.au3>
_GUICtrlComboBox_SelectString($hWnd, $sText [, $iIndex = -1])

参数

$hWnd 控件的控件ID/句柄
$sText 搜索的字符串
$iIndex [可选参数] 指定项目前第一个项目的 0 基 索引

返回值

成功: 返回选定项的索引
失败: 返回 -1

注意/说明

当搜索到达列表框底部,将返回到 wParam 参数指定项的顶部继续搜索.

如果 $iIndex 为 -1,搜索从列表框顶部开始.
可以只选择项目文本开头的第一个字符串作为匹配字符.

如果找到匹配项目时,它将被选中并复制到编辑框.

相关

_GUICtrlComboBox_FindString, _GUICtrlComboBox_FindStringExact, _GUICtrlComboBoxEx_FindStringExact

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_CB = False ; 检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Select String", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    ; 添加字符串
    _GUICtrlComboBox_AddString($hCombo, "This string has been added")
    ; 添加文件
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 选择字符串
    _GUICtrlComboBox_SelectString($hCombo, "This")

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main