函数参考


_GUICtrlComboBox_SetMinVisible

设置组合框下拉列表可见项目的最小数量

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetMinVisible($hWnd, $iMinimum)

参数

$hWnd 控件的控件ID/句柄
$iMinimum 指定可见项的最小数量

返回值

成功: 返回 True
失败: 返回 False

注意/说明

当列表中项目大于最小数目,组合框将使用滚动条.
默认情况下,30 项是可见的最低数量.

如组合控件具有 $CBS_NOINTEGRALHEIGHT 样式,则忽略此函数.

相关

_GUICtrlComboBox_GetMinVisible

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Set Min Visible", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Get Min Visible
    MsgBox(4160, "信息", "Min Visible:" & @TAB & _GUICtrlComboBox_GetMinVisible($hCombo), 3)

    ; 显示下拉框
    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; Set Min Visible
    _GUICtrlComboBox_SetMinVisible($hCombo, 50)

    ; 显示下拉框
    _GUICtrlComboBox_ShowDropDown($hCombo)

    Sleep(500)

    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; Get Min Visible
    MsgBox(4160, "信息", "Min Visible:" & @TAB & _GUICtrlComboBox_GetMinVisible($hCombo), 3)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main