函数参考

_GUICtrlComboBoxEx_SetMinVisible

设置组合框下拉列表项目的最小可见数量

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetMinVisible($hWnd, $iMinimum)

参数

$hWnd 控件句柄
$iMinimum 指定可见项目的最小数量

返回值

成功: 返回 True
失败: 返回 False

注意/说明

当列表中项目大于最小数目,组合框将使用滚动条.
默认情况下,30 项是可见的最低数量.

如组合控件具有 $CBS_NOINTEGRALHEIGHT 样式,则忽略此函数.

相关

_GUICtrlComboBoxEx_GetMinVisible

示例/演示


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hImage, $iImage, $hCombo

    ; 创建 GUI
    $hGUI = GUICreate("ComboBoxEx Set Min Visible", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)
    _GUICtrlComboBoxEx_BeginUpdate($hCombo)

    For $x = 0 To 149
        $iImage = Random(0, 8, 1)
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $iImage, $iImage)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    MsgBox(4160, "信息", "Min Vis.: " & _GUICtrlComboBoxEx_GetMinVisible($hCombo))
    MsgBox(4160, "信息", "Set Min Vis: " & _GUICtrlComboBoxEx_SetMinVisible($hCombo, 50))
    MsgBox(4160, "信息", "Min Vis.: " & _GUICtrlComboBoxEx_GetMinVisible($hCombo))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main