函数参考


_GUICtrlEdit_ReplaceSel

替换当前的选择

#include <GuiEdit.au3>
_GUICtrlEdit_ReplaceSel($hWnd, $sText [, $fUndo = True])

参数

$hWnd 控件的控件ID/句柄
$sText 替换的文本.
$fUndo [可选参数] 指定替换是否可以撤消:
 True - 操作可以撤消.
False - 操作不能撤消.

返回值

None.

注意/说明

使用 _GUICtrlEdit_ReplaceSel 替换部份文本.
如果没有选择,替换文本插入到当前插入符位置.

相关

_GUICtrlEdit_GetSel, _GUICtrlEdit_SetSel

示例/演示


#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; 检查传递给 Edit 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[3] = [200, 378, -1]

    ; 创建 GUI
    $hGUI = GUICreate("Edit Replace Sel", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
    GUISetState()

    ; 设置边距
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; 设置文本
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; 设置选择项
    _GUICtrlEdit_SetSel($hEdit, 0, 8)

    MsgBox(4160, "信息", "Replace Sel")
    _GUICtrlEdit_ReplaceSel($hEdit, StringFormat("%d/%2d/%4d", @MON, @MDAY, @YEAR))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main