函数参考


_GUICtrlHeader_GetItemRect

检索给定项目的边界矩形,返回矩形数据数组.

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemRect($hWnd, $iIndex)

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引

返回值

成功: 返回如下格式数组:
        [0] - 矩形左上角 X 坐标
        [1] - 矩形左上角 Y 坐标
        [2] - 矩形右下角 X 坐标
        [3] - 矩形右下角 Y 坐标

注意/说明

None.

相关

_GUICtrlHeader_GetItemRectEx

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

$Debug_HDR = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader, $aRect

    ; 创建 GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加列
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Show column 1 rectangle
    $aRect = _GUICtrlHeader_GetItemRect($hHeader, 0)
    MemoWrite("Column 1 left .: " & $aRect[0])
    MemoWrite("Column 1 top ..: " & $aRect[1])
    MemoWrite("Column 1 right : " & $aRect[2])
    MemoWrite("Column 1 bottom: " & $aRect[3])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite