函数参考

_GUICtrlListView_SetColumnOrderArray

设置列的左到右顺序,使用数组.

#Include <GuiListView.au3>
_GUICtrlListView_SetColumnOrderArray($hWnd, $aOrder)

参数

$hWnd 控件句柄
$aOrder 包含控制中列索引值的数组
数组必须格式化如下:
[0] - 项目数
[1] - 第一列索引
[2] - 第二列索引
[n] - 最后列索引

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlListView_GetColumnOrder, _GUICtrlListView_GetColumnOrderArray, _GUICtrlListView_SetColumnOrder

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $a_order[5] = [4, 3, 2, 0, 1], $hListView

    GUICreate("ListView Set Column Order Array", 400, 300)
    $hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3|Column 4", 2, 2, 394, 268)
    GUISetState()

    ; Set column order
    MsgBox(4160, "信息", "Changing column order")
    _GUICtrlListView_SetColumnOrderArray($hListView, $a_order)

    ; Show column order
    $a_order = _GUICtrlListView_GetColumnOrderArray($hListView)
    MsgBox(4160, "信息", StringFormat("Column order: [%d, %d, %d, %d]", $a_order[1], $a_order[2], $a_order[3], $a_order[4]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main