函数参考

_GUICtrlListView_SetIconSpacing

设置大图标视图的图标间距

#Include <GuiListView.au3>
_GUICtrlListView_SetIconSpacing($hWnd, $iCX, $iCY)

参数

$hWnd 控件句柄
$iCX 图标间距的 X 轴像素单位
$iCY 图标间距的 Y 轴像素单位

返回值

返回如下格式数组:
[0] - 先前的 CX 值
[1] - 先前的 CY 值

注意/说明

 $iCX 与 $iCY 的值相对于图标位图的左上角.
 要使图标之间不重叠,$iCX 或 $iCY 的值必须包括图标的大小,加上图标之间所需的空间量.
 值不包括将导致图标重叠的宽度.

相关

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hImage, $hListView

    ; 创建 GUI
    GUICreate("ListView Set Icon Spacing", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($hListView, $LVS_ICON)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 0)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

    ; Change item spacing
    MsgBox(4160, "信息", "Changing icon spacing")
    _GUICtrlListView_SetIconSpacing($hListView, 32, 32)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main