函数参考


_GUICtrlMenu_CheckRadioItem

选中指定菜单项,并使其成为单选项目

#Include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem($hMenu, $iFirst, $iLast, $iCheck [, $fByPos = True])

参数

$hMenu 菜单句柄
$iFirst 菜单组第一菜单项的标识符或位置,由 $fByPos 参数决定.
$iLast 菜单组最后菜单项的标识符或位置.
$iCheck 菜单项目的标识符或位置,
$fByPos [可选参数] 菜单识别标志:
True - 对于 $iFirst(首个菜单项), $iLast 与 $iCheck 是项目的 0 基位置
False - 对于 $iFirst(首个菜单项), $iLast 与 $iCheck 是项目的标识符

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 这个函数为 $iCheck 指定的项目设置 $MFT_RADIOCHECK (单选)类型标志和 $MFS_CHECKED (选中)状态,
 同时清除同组中所有其他项目的这两个标志.
 选中项目的旁边会显示项目加重号 ● 位图,而不是复选标记位图

相关

_GUICtrlMenu_CheckMenuItem

详情参考

在MSDN中搜索


示例/演示


#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; 创建 GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Create File menu
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $idExit)

    ; Create Edit menu
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $idPaste)

    ; Create Help menu
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $idAbout)

    ; Create Main menu
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Set window menu
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState()

    ; Check Open menu item
    _GUICtrlMenu_CheckRadioItem($hFile, 0, 4, 2)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main