函数参考

_GUICtrlRichEdit_GetFont

获取选定字体的属性,如果没有选择,则获取插入点的字体属性

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetFont($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回如下格式的数组:
[0] - 磅值(注:1 磅=1/72 英寸)
如果选区内的字号是混合的,则返回 0
[1] - 字体名称
如果选区内的字题是混合的,则返回 ""
[2] - 字符集
$ANSI_CHARSET - 0
$BALTIC_CHARSET - 186
$CHINESEBIG5_CHARSET - 136
$EASTEUROPE_CHARSET - 238
$GB2312_CHARSET - 134
$GREEK_CHARSET - 161
$HANGEUL_CHARSET - 129
$MAC_CHARSET - 77
$OEM_CHARSET - 255
$RUSSIAN_CHARSET - 204
$SHIFTJIS_CHARSET - 128
$SYMBOL_CHARSET - 2
$TURKISH_CHARSET - 162
$VIETNAMESE_CHARSET - 163
失败: 设置@error:
@error: 101 - $hWnd 参数值不是句柄

注意/说明

None.

相关

_GUICtrlRichEdit_SetFont

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Initial")
                    Case 2
                        _GUICtrlRichEdit_SetFont($hRichEdit, 15, "Times Roman")
                        Report("2. Set Font")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aRet = _GUICtrlRichEdit_GetFont($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & $aRet[1] & " " & $aRet[0] & " points"
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report