函数参考


_GUICtrlRichEdit_GetParaAlignment

获取选定段落的对齐方式,或如果没有选择,则获取当前段落

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaAlignment($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回一个字符串值,一个分号(;), 与一个范围字符串:
对齐方式:
l - 左对齐.
r - 右对齐.
c - 居中对齐
j - 两端对齐
f - 两端对齐
w - 扩展间隔的两端对齐
范围:
a - 所有(或使用的)选定的段落有这个对齐
f - 第一个选中段落使用此对齐方式, 但其它不使用
c - 当前段落有这个对齐
失败: 返回 "" ,设置 @error
@error: 101 - $hWnd 参数值不是句柄

注意/说明

 Richedit 2.0 不显示两端对齐

相关

_GUICtrlRichEdit_SetParaAlignment

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $iCp, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetParaAlignment($hRichEdit, "r")
                        Report("First paragraph")
                    Case 2
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        _GUICtrlRichEdit_SetParaAlignment($hRichEdit, "c")
                        Report("Second paragraph")
                    Case 3
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Third paragraph")
                        _GUICtrlRichEdit_SetParaAlignment($hRichEdit, "l")
                        Report("Third paragraph")
                    Case 4
                        $iCp = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
                        _GUICtrlRichEdit_SetSel($hRichEdit, $iCp, -1)
                        Report("Alignment of paragraphs in selection")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaAlignment($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report