函数参考


_GUICtrlRichEdit_GetSelText

检索当前选定的文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSelText($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回选定的文本
失败: 返回 False设置@error
@error: -1 - 没有选中的文本
101 - $hWnd 参数值不是句柄

注意/说明

None.

相关

_GUICtrlRichEdit_GetSel

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    _GUICtrlRichEdit_SetSel($hRichEdit, 0, 4)

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("Selected text is" & @CR & _GUICtrlRichEdit_GetSelText($hRichEdit))
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aRet = _GUICtrlRichEdit_GetSelAA($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & $aRet[0] & "," & $aRet[1]
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report