函数参考


_GUICtrlRichEdit_HideSelection

隐藏(或显示)选区

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_HideSelection($hWnd[, $fHide = True])

参数

$hWnd 控件句柄
$fHide [可选参数] True - 隐藏
False - 显示
默认 : 隐藏

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $fHide 必须是 True 或 False

注意/说明

None.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 5)
                        Report("Text is selected")
                    Case 2
                        _GUICtrlRichEdit_HideSelection($hRichEdit, True)
                        Report("Selection is hidden")
                    Case 3
                        _GUICtrlRichEdit_HideSelection($hRichEdit, False)
                        Report("Selection is not hidden")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $sRet = _GUICtrlRichEdit_GetCharAttributes($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & "Char Attributes=" & $sRet
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report