函数参考

_GUICtrlRichEdit_ReplaceText

替换所选的文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_ReplaceText($hWnd, $sText[, $fCanUndo = True])

参数

$hWnd 控件句柄
$sText 替换的文本
$fCanUndo [可选参数] 确定操作是否可以撤消. True (默认) 或 False

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
103 - $fCanUndo 必须是 True 或 False
-1 - 没有选中的文本

注意/说明

None.

相关

_GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_SetText

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $lblMsg, $hRichEdit
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 5)
                    Case 2
                        _GUICtrlRichEdit_ReplaceText($hRichEdit, "1st")
                        GUICtrlSetData($lblMsg, "Text has been replaced")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 3)
                        _GUICtrlRichEdit_ReplaceText($hRichEdit, "")
                        GUICtrlSetData($lblMsg, "1st has been deleted")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main