函数参考


_GUICtrlRichEdit_SetReadOnly

设置或删除只读状态

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetReadOnly($hWnd[, $fState = True])

参数

$hWnd 控件句柄
$fState [可选参数] 状态值:
True - 设置为只读(默认)
False - 设置为读/写

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $fState 参数值既不是 True 也不是 False
700 - 操作失败

注意/说明

None.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    For $i = 1 To 5
        _GUICtrlRichEdit_AppendText($hRichEdit, "Line " & $i & @CR)
    Next
    _GUICtrlRichEdit_AppendText($hRichEdit, "Line 6")
    Report("Initial state")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetReadOnly($hRichEdit)
                        Report("Set to read-only")
                    Case 2
                        _GUICtrlRichEdit_SetReadOnly($hRichEdit, False)
                        Report("Now read-write")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg & @CR & "Try typing some text")
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report