函数参考


_GUICtrlRichEdit_SetSel

设置选择字符的高、低位置

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetSel($hWnd, $iAnchor, $iActive[, $fHideSel = False])

参数

$hWnd 控件句柄
$iAnchor 第一个选中字符的位置
特别值: -1 - 文本尾端
$iActive 最后一个选中字符的位置
特别值: -1 - 文本尾端
$fHideSel [可选参数] True, 隐藏选择(标记)

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $iAnchor 不是正数,也不是 0, 也不是 -1
103 - $iActive 不是正数,也不是 0, 也不是 -1
104 - $fHideSel 必须是 True 或 False

注意/说明

 控件文本的第一字符位置为 1
 $iActive 可以低于 $iAnchor

相关

_GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_IsTextSelected, _GUICtrlRichEdit_GotoCharPos

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0, $iCp1
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 3)
                        Report("1. Initial Character attributes at start of line 1 are")
                    Case 2
                        _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "http://www.autoitscript.com")
                        $iCp1 = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
                        _GUICtrlRichEdit_SetSel($hRichEdit, $iCp1, $iCp1 + 3)
                        Report("2. Character attributes at start of line 2 are")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $sRet = _GUICtrlRichEdit_GetCharAttributes($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & "Char Attributes=" & $sRet
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report