函数参考

_GUICtrlRichEdit_SetTabStops

设置控件制表位

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetTabStops($hWnd, $vTabStops [, $fRedraw = True])

参数

$hWnd 控件句柄
$VTabStops 设置制表符的空间单位:
如果一个字符串,代表分号分隔的制表位位置
如果是数字: 设置制表位的空间单位
$fRedraw [可选参数] 是否刷新控件 - True(默认)或 False

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
103 - $fRedraw 必须是 True 或 False
1021 - $vTabStops 不是字符串,也不是数字
1022 - $vTabStops 是一个字符串,但一个制表位应该是一个正数
1023 - $vTabStops 是一个空字符串
1024 - $vTabStops 是一个数字,但它是 0 或负数

注意/说明

空间单位最初为英寸.
要输入一个标签控件,点击 Ctrl+Tab 组合键

相关

_GUICtrlRichEdit_SetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetTabStops($hRichEdit, 1)
                        GUICtrlSetData($lblMsg, "1. Set tab stops every inch")
                    Case 2
                        _GUICtrlRichEdit_SetTabStops($hRichEdit, "0.5;1.5")
                        GUICtrlSetData($lblMsg, "2. Set tab stops at 0.5 and 1.5 inches")

                        ; 把所有的文本流保存到桌面,这样您可以在 Word 中查看设置.
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main