函数参考

_GUICtrlSlider_GetBuddy

检索特定位置与平滑调节控件合作的窗口句柄

#Include <GuiSlider.au3>
_GUICtrlSlider_GetBuddy($hWnd, $fLocation)

参数

$hWnd 控件句柄
$fLocation 将被检索的合作窗口句柄.这个值可以是下列之一
True - 检索滑块左边合作窗口句柄.
如果平滑调节控件使用 $TBS_VERT 样式, 函数将检索滑块上方的合作窗口.
False - 检索滑块右边合作窗口句柄.
如果平滑调节控件使用 $TBS_VERT 样式, 函数将检索滑块下方的合作窗口.

返回值

成功: 返回 $fLocation 指定位置的合作窗口句柄
失败: 返回 0

注意/说明

None.

相关

_GUICtrlSlider_SetBuddy

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiSlider.au3>

$Debug_S = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hInput, $hInput2, $hSlider

    ; 创建 GUI
    GUICreate("Slider Get Buddy", 400, 296)
    $hSlider = GUICtrlCreateSlider(95, 2, 205, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS, $TBS_ENABLESELRANGE))
    $hInput = GUICtrlCreateInput("0", 2, 25, 90, 20)
    $hInput2 = GUICtrlCreateInput("0", 2, 25, 90, 20)
    GUISetState()

    ; Set buddy to left
    _GUICtrlSlider_SetBuddy($hSlider, True, $hInput)
    ; Set buddy to right
    _GUICtrlSlider_SetBuddy($hSlider, False, $hInput2)

    ; Get Buddy from the left
    MsgBox(4160, "信息", "Buddy Handle: " & _GUICtrlSlider_GetBuddy($hSlider, True))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main