函数参考

_GUICtrlStatusBar_GetParts

检索部件的数量和界限

#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetParts($hWnd)

参数

$hWnd 控件句柄

返回值

返回下面格式的数组:
$aParts[0] - 部件数量
$aParts[1] - 部件 #1 右边界
$aParts[2] - 部件 #2 右边界
$aParts[n] - 部件 #n 右边界

注意/说明

None.

相关

_GUICtrlStatusBar_SetParts

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

$Debug_SB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()

    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; 创建 GUI
    $hGUI = GUICreate("StatusBar Get Parts", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Set/Get parts
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    $aParts = _GUICtrlStatusBar_GetParts($hStatus)
    For $iI = 1 To $aParts[0]
        MemoWrite("Part " & $iI & " width .: " & $aParts[$iI])
    Next

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite