函数参考


_GUICtrlStatusBar_SetSimple

指定是否显示简单文本状态窗口, 或显示所有窗口部件

#Include <GuiStatusBar.au3>
_GUICtrlStatusBar_SetSimple($hWnd, $fSimple = True)

参数

$hWnd 控件句柄
$fSimple 设置 Windows 显示
 True - 窗口显示简单文本
False - 窗口显示多个部件

返回值

None.

注意/说明

None.

相关

_GUICtrlStatusBar_IsSimple

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

$Debug_SB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()

    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; 创建 GUI
    $hGUI = GUICreate("StatusBar Set Simple", 400, 300)

    $hStatus = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get/Set simple format
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))
    _GUICtrlStatusBar_SetSimple($hStatus, True)
    MemoWrite("Simple mode on .: " & _GUICtrlStatusBar_IsSimple($hStatus))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite