函数参考


_GUICtrlToolbar_GetButtonRect

检索按钮的矩形,返回数据数组.

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonRect($hWnd, $iCommandID)

参数

$hWnd 控件句柄
$iCommandID 按钮命令 ID

返回值

成功: 返回数组的格式如下:
[0] - 矩形左上角 X 坐标
[1] - 矩形左上角 Y 坐标
[2] - 矩形右下角 X 坐标
[3] - 矩形右下角 Y 坐标

注意/说明

None.

相关

_GUICtrlToolbar_GetButtonRectEx

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aRect
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Show Save button rectangle
    $aRect = _GUICtrlToolbar_GetButtonRect($hToolbar, $idSave)
    MemoWrite("Save Button Rect")
    MemoWrite("----------------")
    MemoWrite("Left ...: " & $aRect[0])
    MemoWrite("Top ....: " & $aRect[1])
    MemoWrite("Right ..: " & $aRect[2])
    MemoWrite("Bottom .: " & $aRect[3])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite