函数参考


_GUICtrlToolbar_GetStyleTransparent

检索控件是否为透明的样式

#Include <GuiToolBar.au3>
_GUICtrlToolbar_GetStyleTransparent($hWnd)

参数

$hWnd 控件句柄

返回值

True: 该样式存在返回
False: 该样式不存在

注意/说明

None.

相关

_GUICtrlToolbar_SetStyleTransparent

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $fStyle
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetBkColor(0xffffff)
    GUISetState()

    ; 添加标准系统位图
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; 修改控件样式
    $fStyle = _GUICtrlToolbar_GetStyleTransparent($hToolbar)
    MsgBox(4096, "信息", "Toolbar has transparent style .: " & $fStyle)
    GUISetState(@SW_LOCK)
    _GUICtrlToolbar_SetStyleTransparent($hToolbar, Not $fStyle)
    GUISetState(@SW_UNLOCK)
    MsgBox(4096, "信息", "Toolbar has transparent style .: " & _GUICtrlToolbar_GetStyleTransparent($hToolbar))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main