函数参考


_GUICtrlToolbar_SetBitmapSize

设置工具栏位图图像的大小

#Include <GuiToolBar.au3>
_GUICtrlToolbar_SetBitmapSize($hWnd, $iWidth, $iHeight)

参数

$hWnd 控件句柄
$iWidth 位图图像宽度像素值
$iHeight 位图图像高度像素值

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 位图大小在添加到工具栏之前设置
 如果应用程序不设置位图的大小,默认大小 15 到 16 像素

相关

示例/演示


#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; 创建 GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState()

    ; 添加标准系统位图
    _GUICtrlToolbar_SetBitmapSize($hToolbar, 24, 24)
    _GUICtrlToolbar_LoadImages($hToolbar, $IDB_STD_LARGE_COLOR)

    ; 添加字符串
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; 添加按钮
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main