函数参考

_GUICtrlTreeView_ExpandedOnce

检索项目的子项列表是否至少展开一次

#Include <GuiTreeView.au3>
_GUICtrlTreeView_ExpandedOnce($hWnd, $hItem)

参数

$hWnd 控件句柄
$hItem 项目句柄

返回值

返回True: 项目已展开至少一次
返回False: 项目尚未展开至少一次

注意/说明

None.

相关

_GUICtrlTreeView_Expand

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[5], $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Expanded Once", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 4
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    MsgBox(4160, "信息", "Expand item 0")
    _GUICtrlTreeView_Expand($hTreeView, $hItem[0])

    MsgBox(4160, "信息", "Collapse item 0")
    _GUICtrlTreeView_Expand($hTreeView, $hItem[0], False)

    MsgBox(4160, "信息", "Item 0 expanded at least once? " & _GUICtrlTreeView_ExpandedOnce($hTreeView, $hItem[0]))
    MsgBox(4160, "信息", "Item 1 expanded at least once? " & _GUICtrlTreeView_ExpandedOnce($hTreeView, $hItem[1]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main