函数参考

_GUICtrlTreeView_GetISearchString

检索增量搜索字符串

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetISearchString($hWnd)

参数

$hWnd 控件ID/句柄

返回值

成功: 返回增量搜索字符串(如果控件是在增量搜索模式时)
失败: 返回 ""

注意/说明

增量搜索字符串是指作为搜索项目依据的用户输入字符串

相关

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hImage, $hTreeView
    Local $sText[6] = ["AutoIt", "freeware", "BASIC-like", "scripting", "language", "automating"]
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get ISearch String", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($hTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        _GUICtrlTreeView_Add($hTreeView, 0, $sText[$x], $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    Send($sText[Random(0, 5, 1)])
    MsgBox(4160, "信息", "ISearch String: " & _GUICtrlTreeView_GetISearchString($hTreeView))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main