函数参考


_GUICtrlTreeView_GetNextSibling

检索同级别的下一个项目

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetNextSibling($hWnd, $hItem)

参数

$hWnd 控件ID/句柄
$hItem 项目句柄

返回值

成功: 同级项目的下一项目句柄
失败: 返回 0

注意/说明

None.

相关

_GUICtrlTreeView_GetNext, _GUICtrlTreeView_GetPrevSibling

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()

    Local $hItem[10], $hRandItem, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get Next Sibling", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 3
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
        Next
    Next
    $hItem[4] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", 4), $hTreeView)
    For $x = 5 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 1 To Random(2, 10, 1)
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hRandItem = Random(0, 8, 1)
    MsgBox(4160, "信息", StringFormat("Index %d, Next: %s", $hRandItem, _GUICtrlTreeView_GetNextSibling($hTreeView, $hItem[$hRandItem])))
    _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetNextSibling($hTreeView, $hItem[$hRandItem]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main