函数参考


_GUIScrollBars_GetScrollInfo

检索滚动控件的参数,使用数据结构.

#Include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollInfo($hWnd, $fnBar, ByRef $tSCROLLINFO)

参数

$hWnd 窗口句柄
$fnBar 指定滚动控件的类型. 参数可以是以下值之一:
$SB_CTL - 检索滚动控件的参数. $hWnd 参数必须是滚动控件的窗口句柄.
$SB_HORZ - 检索窗口标准水平滚动控件参数.
$SB_VERT - 检索窗口标准垂直滚动控件参数.
$tSCROLLINFO $tagSCROLLINFO 类型结构

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 以上常数需要 ScrollBarConstants.au3

相关

_GUIScrollBars_GetScrollInfoEx, $tagSCROLLINFO, _GUIScrollBars_SetScrollInfo

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GuiScrollBars.au3>
#include <ScrollBarConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $GUIMsg, $hGUI, $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $iMemo = GUICtrlCreateEdit("", 2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($iMemo, $GUI_DOCKALL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState()

    _GUIScrollBars_Init($hGUI)

    DllStructSetData($tSCROLLINFO, "cbSize", DllStructGetSize($tSCROLLINFO))
    DllStructSetData($tSCROLLINFO, "fMask", $_SCROLLBARCONSTANTS_SIF_ALL)
    _GUIScrollBars_GetScrollInfo($hGUI, $SB_HORZ, $tSCROLLINFO)
    MemoWrite("Horizontal" & @CRLF & "--------------------------------------")
    MemoWrite("nPage....: " & DllStructGetData($tSCROLLINFO, "nPage"))
    MemoWrite("nPos.....: " & DllStructGetData($tSCROLLINFO, "nPos"))
    MemoWrite("nMin.....: " & DllStructGetData($tSCROLLINFO, "nMin"))
    MemoWrite("nMax.....: " & DllStructGetData($tSCROLLINFO, "nMax"))
    MemoWrite("nTrackPos: " & DllStructGetData($tSCROLLINFO, "nTrackPos"))

    DllStructSetData($tSCROLLINFO, "cbSize", DllStructGetSize($tSCROLLINFO))
    DllStructSetData($tSCROLLINFO, "fMask", $_SCROLLBARCONSTANTS_SIF_ALL)
    _GUIScrollBars_GetScrollInfo($hGUI, $SB_VERT, $tSCROLLINFO)
    $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hGUI, $SB_VERT)
    MemoWrite(@CRLF & "Vertical" & @CRLF & "--------------------------------------")
    MemoWrite("nPage....: " & DllStructGetData($tSCROLLINFO, "nPage"))
    MemoWrite("nPos.....: " & DllStructGetData($tSCROLLINFO, "nPos"))
    MemoWrite("nMin.....: " & DllStructGetData($tSCROLLINFO, "nMin"))
    MemoWrite("nMax.....: " & DllStructGetData($tSCROLLINFO, "nMax"))
    MemoWrite("nTrackPos: " & DllStructGetData($tSCROLLINFO, "nTrackPos"))

    While 1
        $GUIMsg = GUIGetMsg()

        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite