函数参考


_IEFormGetCollection

返回文档内代表表单的对象变量集或按索引的单一表单.

#include <IE.au3>
_IEFormGetCollection ( ByRef $o_object [, $i_index = -1] )

参数

$o_object InternetExplorer.Application, 窗口或者框架对象的对象变量
$i_index [可选参数]: 指定返回一个集合还是索引对象
0 或者正整数返回一个索引对象
-1 = (默认)返回一个集合

返回值

成功: 返回 1
失败: 返回 0并设置@ERROR
@Error: 0 ($_IEStatus_Success) = 无错误
3 ($_IEStatus_InvalidDataType) = 无效数据类型
4 ($_IEStatus_InvalidObjectType) = 无效对象类型
5 ($_IEStatus_InvalidValue) = 无效值
7 ($_IEStatus_NoMatch) = 不匹配
@Extended: 包含无效参数数量

注意/说明

None.

相关

_IEFormGetObjByName, _IEFormReset, _IEFormSubmit

示例/演示


; *******************************************************
; 示例 1 - 根据基于 0 的索引获取到指定表单的引用,
;               此时是页面上首个表单
; *******************************************************

#include <IE.au3>

Local $oIE = _IECreate("http://www.google.com")
Local $oForm = _IEFormGetCollection($oIE, 0)
Local $oQuery = _IEFormElementGetCollection($oForm, 1)
_IEFormElementSetValue($oQuery, "AutoIt IE.au3")
_IEFormSubmit($oForm)

; *******************************************************
; 示例 2 - 获取到页面上表单集合的引用,
;               然后对其进行循环显示其中每个的信息
; *******************************************************

#include <IE.au3>

$oIE = _IECreate("http://www.autoitscript.com")
Local $oForms = _IEFormGetCollection($oIE)
MsgBox(4096, "Forms Info", "There are " & @extended & " forms on this page")
For $oForm In $oForms
    MsgBox(4096, "Form Info", $oForm.name)
Next

; *******************************************************
; 示例 3 - 获取到页面上表单集合的引用,
;               然后对其进行循环显示其中每个的信息
;               演示表单索引的使用
; *******************************************************

#include <IE.au3>

$oIE = _IECreate("http://www.autoitscript.com")
$oForms = _IEFormGetCollection($oIE)
Local $iNumForms = @extended
MsgBox(4096, "Forms Info", "There are " & $iNumForms & " forms on this page")
For $i = 0 To $iNumForms - 1
    $oForm = _IEFormGetCollection($oIE, $i)
    MsgBox(4096, "Form Info", $oForm.name)
Next