函数参考


_Net_Share_FileClose

强制关闭资源

#Include <NetShare.au3>
_Net_Share_FileClose($sServer, $iFileID)

参数

$sServer 指定 DNS 或 NetBIOS 远程服务器上执行函数的名称
如果此参数为空, 在本地计算机上使用.
$iFileID 指定关闭打开资源实例的文件标识符

返回值

成功: 返回 True
失败: 返回 False

注意/说明

系统管理员,服务器操作员或本地组成员才能执行此功能

相关

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $sServer, $aInfo

    ; 创建 GUI
    GUICreate("NetShare", 400, 300)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 获取服务器和共享信息
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; 枚举服务器上打开的文件
    $aInfo = _Net_Share_FileEnum($sServer)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aInfo[0][0])

    ; 强制关闭已打开的名称为 "Test.txt" 的任意文件
    For $iI = 1 To $aInfo[0][0]
        If StringInStr($aInfo[$iI][3], "Test.txt") > 0 Then
            _Net_Share_FileClose($sServer, $aInfo[$iI][0])
            MemoWrite("Closed file")
        EndIf
    Next

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite