函数参考


_SoundPause

暂停一个播放中的声音.

#include <Sound.au3>
_SoundPause ( $aSnd_id )

参数

$aSnd_id 由 _SoundOpen() 返回的声音数组 ID 或文件名称

返回值

成功: 返回 1
失败: 返回 0,设置@error:
@error: 1 = Pause 失败
3 = 无效的声音标识. 使用 _SoundOpen()返回的数组或有效文件名.

注意/说明

None.

相关

_SoundResume, _SoundOpen, _SoundPlay

示例/演示


#include <Sound.au3>

Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
    MsgBox(4096, "错误", "文件不存在")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ;赋值, 因为 @extended 可能会在 DllCall 后被设置成其它返回值
    Local $tText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($tText), "int", 128)
    MsgBox(4096, "错误", "The open failed." & @CRLF & "Error Number: " & $iExtended & @CRLF & "Error Description: " & DllStructGetData($tText, 1) & @CRLF & "Please Note: The sound may still play correctly.")
Else
    MsgBox(4096, "Success", "The file opened successfully")
EndIf
_SoundPlay($aSound)
Sleep(1000)

_SoundPause($aSound)
Sleep(1000)

_SoundResume($aSound)

While 1
    Sleep(100)
    If _SoundPos($aSound, 2) >= _SoundLength($aSound, 2) Then ExitLoop
WEnd

_SoundClose($aSound)