AU3中,如果加载网页!

tobehacker

请问一下,AU3在控件里面如何加载网页?

比转成EXE后.点击之后,出面窗体,窗体里面显示的是百度...

请教高手.谢了...

[ 本帖最后由 tobehacker 于 2008-5-10 13:55 编辑 ]

sanhen

#include <IE.au3>
_IECreate ( [$s_Url = "about:blank" [, $f_tryAttach = 0 [, $f_visible = 1 [, $f_wait = 1 [, $f_takeFocus = 1]]]]] )

tobehacker

这个是打开网页吧.我的意思是在窗体中插入网页.这个可以实现吗?如果可以.请说详细一点好吗?我是菜鸟!!

bob

看帮助文件GUICtrlCreateObj函数
例子就是GUI上GUI中嵌入Internet Explorer 控件

tobehacker

谢谢楼上的和楼上楼上的.....搞定了..

gdft520

支持一下！

yinui

AU3里面就有示范的例子了，LZ好好找找

yinui

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Example()

; Simple example: Embedding an Internet Explorer Object inside an AutoIt GUI
;
; See also: http://msdn.microsoft.com/worksh ... nternetexplorer.asp
Func Example()
        Local $oIE, $GUIActiveX, $GUI_Button_Back, $GUI_Button_Forward
        Local $GUI_Button_Home, $GUI_Button_Stop, $msg
       
        $oIE = ObjCreate("Shell.Explorer.2")

        ; Create a simple GUI for our output
        GUICreate("Embedded Web control Test", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
        $GUIActiveX = GUICtrlCreateObj ($oIE, 10, 40, 600, 360)
        $GUI_Button_Back = GUICtrlCreateButton("Back", 10, 420, 100, 30)
        $GUI_Button_Forward = GUICtrlCreateButton("Forward", 120, 420, 100, 30)
        $GUI_Button_Home = GUICtrlCreateButton("Home", 230, 420, 100, 30)
        $GUI_Button_Stop = GUICtrlCreateButton("Stop", 330, 420, 100, 30)

        GUISetState()       ;Show GUI

        $oIE.navigate("http://10.8.13.119/launcher/")

        ; Waiting for user to close the window
        While 1
                $msg = GUIGetMsg()

                Select
                        Case $msg = $GUI_EVENT_CLOSE
                                ExitLoop
                        Case $msg = $GUI_Button_Home
                                $oIE.navigate("http://www.autoitscript.com")
                        Case $msg = $GUI_Button_Back
                                $oIE.GoBack
                        Case $msg = $GUI_Button_Forward
                                $oIE.GoForward
                        Case $msg = $GUI_Button_Stop
                                $oIE.Stop
                EndSelect
               
        WEnd

        GUIDelete()
EndFunc   ;==>Example