函数参考

GUICtrlCreateAvi

在GUI上创建一个AVI视频剪辑控件.

GUICtrlCreateAvi ( 文件名, 子文件ID, 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

文件名 视频文件名.仅支持 .avi 格式的文件.
子文件ID 要使用的子文件ID.若该文件只含有一个视频剪辑则请设为 0.
左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(default)(-1):$ACS_TRANSPARENT
除非有指定 $ACS_NONTRANSPARENT 否则总是使用 $ACS_TRANSPARENT.
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表 .

返回值

成功: 返回控件标识符(控件ID).
失败: 返回值为 0.

注意/说明

若要获得控件的各种值请查看 GUICtrlRead.
要设置或者修改控件信息,请参考 GUICtrlUpdate....

若要在控件被创建后立即播放该视频剪辑则请添加 $ACS_AUTOPLAY 样式.
您可以通过 GUICtrlSetState 设置状态值为1或0即可播放或停止剪辑.请看下面的示例.

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_AVI, 新样式,...).

要使用上方指定的值,您必须包含 #include <AVIConstants.au3> 在你的脚本.

默认大小为 $GUI_DOCKSIZE.

相关

GUICoordMode (option), GUICtrlUpdate..., GUIGetMsg

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $ani1, $buttonstart, $buttonstop, $msg

    GUICreate("My GUI Animation", 360, 200)
    $ani1 = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 50, 10)

    $buttonstart = GUICtrlCreateButton("开始", 100, 150, 70, 22)
    $buttonstop = GUICtrlCreateButton("停止", 200, 150, 70, 22)

    GUISetState()

    ; 运行界面,直到窗口被关闭
    While 1
        $msg = GUIGetMsg()

        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop

            Case $msg = $buttonstart
                GUICtrlSetState($ani1, 1)

            Case $msg = $buttonstop
                GUICtrlSetState($ani1, 0)

        EndSelect
    WEnd
EndFunc   ;==>Example