函数参考

GUICtrlCreateCombo

在GUI上创建一个组合列表框(ComboBox)控件.

GUICtrlCreateCombo ( "文本", 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

文本 组合列表框(ComboBox)控件显示的文本.
左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(-1):$CBS_DROPDOWN, $CBS_AUTOHSCROLL, $WS_VSCROLL
强制性样式: $WS_TABSTOP
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表.

返回值

成功: 返回控件标识符(控件ID).
失败: 返回值为 0.

注意/说明

若要获得控件的各种值,请参考 GUICtrlRead.
要设置或者修改控件信息,请参考 GUICtrlUpdate....

在 Windows XP/2003 下系统会自动调整打开(弹出)的选择框控件的大小,而在其它的 Windows 版本下则可以利用"高度"参数定义它的大小.

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_COMBO, 新样式,...).

要使用上方指定的值,您必须包含 #include <ComboConstants.au3> 在你的脚本中.

默认大小为: $GUI_DOCKHEIGHT.

相关

GUICoordMode (Option), GUICtrlSetData, GUICtrlUpdate..., GUIGetMsg

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $msg
    GUICreate("My GUI combo")  ; 创建一个对话框,并居中显示

    GUICtrlCreateCombo("item1", 10, 10) ; 创建一个组合列表框(ComboBox)控件
    GUICtrlSetData(-1, "item2|item3", "item3") ; 在列表框中添加新的项目，并设置一个新的默认值

    GUISetState()

    ; 运行界面,直到窗口被关闭
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example