函数参考

GUICtrlCreateRadio

在GUI上创建一个单选框(Radio)控件.

GUICtrlCreateRadio ( "文本", 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

文本 单选框(Radio)控件显示的文本.
左侧 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(default)(-1):无
强制性样式: $BS_AUTORADIOBUTTON 和 $WS_TABSTOP (若该单选按钮是某组中的第一个单选按钮)
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表 .

返回值

成功: 返回控件标识符(控件ID).
失败: 返回值为 0.

注意/说明

若要获得控件的各种值请查看 GUICtrlRead.
若要设置或修改控件的各种信息请查看 GUICtrlUpdate....

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_RADIO, 新样式,...).

要使用上方指定的值,您必须包含 #include <ButtonConstants.au3> 在你的脚本.

默认大小为: $GUI_DOCKHEIGHT.

相关

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $radio1, $radio2, $msg
    GUICreate("My GUI radio") ; will create a dialog box that when displayed is centered

    $radio1 = GUICtrlCreateRadio("Radio 1", 10, 10, 120, 20)
    $radio2 = GUICtrlCreateRadio("Radio 2", 10, 40, 120, 20)
    GUICtrlSetState($radio2, $GUI_CHECKED)

    GUISetState() ; will display an  dialog box with 1 checkbox

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $radio1 And BitAND(GUICtrlRead($radio1), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox(4160, 'Info:', 'You clicked the Radio 1 and it is Checked.')
            Case $msg = $radio2 And BitAND(GUICtrlRead($radio2), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox(4160, 'Info:', 'You clicked on Radio 2 and it is Checked.')
        EndSelect
    WEnd
EndFunc   ;==>Example