函数参考

GUICtrlCreateSlider

在GUI上创建一个滑动条(Slider)控件.

GUICtrlCreateSlider ( 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(default)(-1):$TBS_AUTOTICKS
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表.

返回值

成功: 返回新控件的控件标识符(控件ID).
失败: 返回值为 0.

注意/说明

若要获得控件的各种值,请参考 GUICtrlRead.
要设置或者修改控件信息,请参考 GUICtrlUpdate....

若要更新滑块的位置请使用 GUICtrlSetData.
若要设置最小值和最大值请使用 GUICtrlSetLimit.

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_SLIDER, 新样式,...).

要使用上方指定的值,您必须包含 #include <SliderConstants.au3> 在你的脚本中.

默认大小为: $GUI_DOCKAUTO

相关

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $slider1, $button, $msg

    GUICreate("slider", 220, 100, 100, 200)
    GUISetBkColor(0x00E0FFFF) ; will change background color

    $slider1 = GUICtrlCreateSlider(10, 10, 200, 20)
    GUICtrlSetLimit(-1, 200, 0) ; change min/max value
    $button = GUICtrlCreateButton("Value?", 75, 70, 70, 20)
    GUISetState()
    GUICtrlSetData($slider1, 45) ; set cursor

    Do
        $msg = GUIGetMsg()

        If $msg = $button Then
            MsgBox(4096, "slider1", GUICtrlRead($slider1), 2)
        EndIf
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example