函数参考

GUICtrlSetFont

设置指定控件的字体.

GUICtrlSetFont (控件ID, 大小 [, 权值 [, 属性 [, 字体名 [, 质量 ]]]] )

参数

控件ID 控件标识符(控件ID),可由 GUICtrlCreate... 函数的返回值获得.
大小 字体大小(默认值为 8.5).
权值 [可选参数] 字体权值(weight)(默认值为 400 = 正常).
属性 [可选参数] 定义字体样式,斜体:2 下划线:4 删除线:8 (可按需把对应数值加起来,比如 2+4 = 斜体,同时带有下划线).
字体名 [可选参数] 要使用的字体名.
质量 [可选参数] 字体质量选择.(默认为PROOF_QUALITY=2).

返回值

成功: 返回值为1.
失败: 返回值为0.

注意/说明

在默认情况下,控件将使用 GUISetFont 设置的字体.

字体大小可以是小数,比如 8.5.

一些像标签(labels)这样的控件, 默认大小使用8.5代替9以适合 Windows 主题的值.

请查看附录的完整字体列表以了解各个系统支持的字体.

质量参数请参考 MSDN, 一些 windows XP 安装需要 CLEARTYPE_QUALITY=5

相关

GUICtrlCreate..., GUISetFont

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $font, $msg

    GUICreate("My GUI") ; will create a dialog box that when displayed is centered

    $font = "Comic Sans MS"
    GUICtrlCreateLabel("underlined label", 10, 20)
    GUICtrlSetFont(-1, 9, 400, 4, $font) ; will display underlined characters

    GUICtrlCreateLabel("italic label", 10, 40)
    GUICtrlSetFont(-1, 9, 400, 2, $font) ; will display italic characters

    GUISetFont(9, 400, 8, $font) ; will display strike characters
    GUICtrlCreateLabel("strike label", 10, 60)

    GUISetState() ; will display an empty dialog box

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example