函数参考

GUICtrlSetPos

调整某个控件在窗口中的坐标位置.

GUICtrlSetPos ( 控件ID, 左侧 [, 顶部 [, 宽度 [, 高度]]] )

参数

控件ID 控件标识符(控件ID),可由 GUICtrlCreate... 函数的返回值获得.
左侧 控件左侧的位置.
顶部 [可选参数] 控件上方的位置.
宽度 [可选参数] 控件的宽度.
高度 [可选参数] 控件的高度.

返回值

成功: 返回值为1.
失败: 返回值为0.

注意/说明

如果使用 Default 关键字, 当前的值不会出现任何改变.

相关

GUICtrlCreate...

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $right, $label, $button, $msg

    GUICreate("My GUI position") ; will create a dialog box that when displayed is centered

    $right = 0
    $label = GUICtrlCreateLabel("my moving label", 10, 20)

    $button = GUICtrlCreateButton("Click to close", 50, 50)
    GUICtrlSetState(-1, $GUI_FOCUS) ; the focus is on this button

    GUISetState()

    While 1
        $msg = GUIGetMsg()

        If $msg = $button Or $msg = $GUI_EVENT_CLOSE Then Exit
        If $right = 0 Then
            $right = 1
            GUICtrlSetPos($label, 20, 20)
        Else
            $right = 0
            GUICtrlSetPos($label, 10, 20)
        EndIf
        Sleep(100)
    WEnd
EndFunc   ;==>Example