函数参考

GUISetStyle

改变窗口样式.

GUISetStyle ( 样式 [,扩展样式 [, 窗口句柄]] )

参数

样式 定义的窗口的样式. 参考 GUI 控件样式附录.

-1为不改变.
扩展样式 [可选参数] 定义的窗口扩展样式. 参考 扩展样式表 . 默认值为 -1.
-1为不改变.
窗口句柄 [可选参数] 由 GUICreate 返回的窗口句柄 (默认(default)为上一使用的窗口句柄).

返回值

成功: 返回 1.
失败: 返回 0.

注意/说明

程序并不会检查设置样式的值, 也不会和已经定义的控件进行交互. 这是为了和不同的程序设计进行兼容.

相关

GUIGetStyle

示例/演示


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $NewStyle = False, $Style, $Msg

    GUICreate("Gui Style", 260, 100)
    $Style = GUICtrlCreateButton("Set Style", 45, 50, 150, 20)
    GUISetState()

    While 1
        $Msg = GUIGetMsg()
        Switch $Msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $Style
                If Not $NewStyle Then
                    GUISetStyle(BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), BitOR($WS_EX_CLIENTEDGE, $WS_EX_TOOLWINDOW))
                    GUICtrlSetData($Style, 'Undo Style')
                    $NewStyle = True
                Else
                    GUISetStyle(BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU), 0)
                    GUICtrlSetData($Style, 'Set Style')
                    $NewStyle = False
                EndIf
            Case Else
        EndSwitch
    WEnd
EndFunc   ;==>Example