函数参考

IniWriteSection

将数据写入到标准INI文件的一个字段.

IniWriteSection ( "文件名", "字段", "数据" [, 索引] )

参数

文件名 .ini 文件的路径.
字段 .ini 文件中的字段名称.
数据 需要写入的数据. 数据可以是一个字符串或者一个数组.如果是一个字符串,数据请按照标准的INI文件格式写入 键 = 值 这样成对的写入,如果有多行,请使用 @LF 换行.如果数据为一个数组,则必须为一个二维数组,且第二维必须含有两个元素.
索引 [可选参数] If an array is passed as data, this specifies the index to start writing from. By default, this is 1 so that the return value of IniReadSection() can be used immediately. For manually created arrays, this value may need to be different depending on how the array was created. This parameter is ignored if a string is passed as data.

返回值

成功: 返回 1.
失败: 返回 0. 如果 @error 被设置为1,那么您的数据格式是错误的.

注意/说明

一个标准的INI文件的结构如下:
[段名]
关键字=数值
若目标文件并不存在,则程序将自动创建该文件,关键字和段将被添加到后面部分而且并不按任何规则排列.
如果字段是存在的,数据将会覆盖.

相关

IniDelete, IniRead, IniReadSection, IniReadSectionNames, IniWrite, IniRenameSection

示例/演示


; INI文件写入演示,文件将会在桌面创建.
Local $sIni = @DesktopDir & "\AutoIt-Test.ini"

; 将数据写入到标准INI文件的一个字段.
Local $sData = "Key1=Value1" & @LF & "Key2=Value2" & @LF & "Key3=Value3"
IniWriteSection($sIni, "Section1", $sData)

;创建一个新的字段,并将数组数据写入.
Local $aData1 = IniReadSection($sIni, "Section1")   ; 读取刚刚写入的内容.
For $i = 1 To UBound($aData1) - 1
    $aData1[$i][1] &= "-" & $i  ; 更改某些数据
Next

IniWriteSection($sIni, "Section2", $aData1) ; 写入新的数据

; 创建一个自定义的二维数组,并将数组数据写入.
Local $aData2[3][2] = [["FirstKey", "FirstValue"],["SecondKey", "SecondValue"],["ThirdKey", "ThirdValue"]]
;定义数组元素索引,由索引0开始写入.
IniWriteSection($sIni, "Section3", $aData2, 0)