函数参考

_WinAPI_CreateJobObject

创建或打开作业对象.

#Include <WinAPIEx.au3>
_WinAPI_CreateJobObject ( [$sName [, $tSecurity] )

参数

$sName [可选参数] 作业的名称. 名称区分大小写.
 如果此参数为 0, 则创建一个无名称作业.
$tSecurity [可选参数] $tagSECURITY_ATTRIBUTES 结构
 指定作业对象的安全描述符; 并确定子进程是否可以继承返回的句柄.
 如果此参数为 0, 作业对象获取默认的安全描述符, 且句柄不能被继承.

返回值

成功: 返回作业对象句柄. 如果该对象在函数调用前已存在,
函数返回现行作业对象的句柄.
失败: 返回 0,并设置@error标志为非 0 值.

注意/说明

当创建作业时, 其统计信息初始化为 0, 所有参数都无效, 而且没有相关的进程.
 要指定进程到作业对象, 使用 _WinAPI_AssignProcessToJobObject() 函数.
 要为作业设置限制范围, 使用 _WinAPI_SetInformationJobObject() 函数.
 要查询统计信息,使用 _WinAPI_QueryInformationJobObject() 函数.
 全部与作业关联的进程必须运行于同一会话期.
 作业关联第一个被分配该作业的进程会话.
 要关闭作业对象的句柄,使用 _WinAPI_CloseHandle() 函数.
 作业被销毁时, 最后的句柄已经结束, 所有相关的进程也已经退出.

相关

详情参考

在MSDN中搜索


示例/演示


#Include <APIConstants.au3>
#Include <WinAPIEx.au3>

Opt('MustDeclareVars', 1)

Global Const $sTemp = @TempDir & '\Test.au3'

Global $hFile

; 创建临时 .au3 文件
$hFile = FileOpen($sTemp, 2)
For $i = 1 To 3
    FileWriteLine($hFile, 'Run(@SystemDir & "\calc.exe")')
Next
FileClose($hFile)

; 运行 "calc.exe" 3 次并等待您关闭所有的 3 个进程
_RunWaitEx(@AutoItExe & ' /AutoIt3ExecuteScript "' & $sTemp & '"')

; 删除临时 .au3 文件
FileDelete($sTemp)

Func _RunWaitEx($sCmd)

    ; 根据 amel27 的设想

    Local $tProcess = DllStructCreate($tagPROCESS_INFORMATION)
    Local $tStartup = DllStructCreate($tagSTARTUPINFO)
    Local $tInfo = DllStructCreate($tagJOBOBJECT_BASIC_ACCOUNTING_INFORMATION)
    Local $hJob, $hProcess, $hThread

    $hJob = _WinAPI_CreateJobObject()
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    DllStructSetData($tStartup, 'Size', DllStructGetSize($tStartup))
    If Not _WinAPI_CreateProcess('', $sCmd, 0, 0, 0, BitOR($CREATE_BREAKAWAY_FROM_JOB, $CREATE_SUSPENDED), 0, 0, DllStructGetPtr($tStartup), DllStructGetPtr($tProcess)) Then
        Return SetError(1, _WinAPI_CloseHandle($hJob), 0)
    EndIf
    $hProcess = DllStructGetData($tProcess, 'hProcess')
    $hThread = DllStructGetData($tProcess, 'hThread')
    _WinAPI_AssignProcessToJobObject($hJob, $hProcess)
    _WinAPI_ResumeThread($hThread)
    _WinAPI_CloseHandle($hThread)
    Do
        If Not _WinAPI_QueryInformationJobObject($hJob, 1, $tInfo) Then
            ExitLoop
        EndIf
        Sleep(100)
    Until Not DllStructGetData($tInfo, 'ActiveProcesses')
    _WinAPI_CloseHandle($hProcess)
    _WinAPI_CloseHandle($hJob)
    Return 1
EndFunc   ;==>_RunWaitEx

Func _WinAPI_ResumeThread($hThread)

    Local $Ret = DllCall('kernel32.dll', 'dword', 'ResumeThread', 'ptr', $hThread)

    If (@error) Or (_WinAPI_DWordToInt($Ret[0]) = -1) Then
        Return SetError(1, 0, -1)
    EndIf
    Return $Ret[0]
EndFunc   ;==>_WinAPI_AssignProcessToJobObject