函数参考

_WinAPI_ShellSetLocalizedName

在SHELL文件夹中设置文件的本地化文件名

#Include <WinAPIEx.au3>
_WinAPI_ShellSetLocalizedName ( $sPath, $sModule, $iResID )

参数

$sPath 目标文件路径
$sModule 包含指定本地化文件名字符串资源的模块的路径
$iResID 本地化文件名资源ID

返回值

成功: 返回 1
失败: 返回 0并设置@error非0; @extended标记可能包含系统错误代码.

注意/说明

设置该字符串时, Windows浏览器显示该字符串以替换文件名. 文件路径不会改变.

最低系统要求: Windows Vista

相关

详情参考

在MSDN中搜索


示例/演示


#Include <APIConstants.au3>
#Include <WinAPIEx.au3>

Opt('MustDeclareVars', 1)

If _WinAPI_GetVersion() < '6.0' Then
    MsgBox(16, 'Error', 'Require Windows Vista or later.')
    Exit
EndIf

Global Const $sDll = @ScriptDir & '\Extras\Resources.dll'
Global Const $sDir = @ScriptDir & '\Temporary Folder'

If Not FileExists($sDll) Then
    MsgBox(16, 'Error', $sDll & ' not found.')
    Exit
EndIf

If Not DirCreate($sDir) Then
    MsgBox(16, 'Error', 'Unable to create folder.')
    Exit
EndIf

_WinAPI_ShellOpenFolderAndSelectItems($sDir)
MsgBox(0x00040040, '', 'Press OK to set localized name for "' & _WinAPI_PathStripPath($sDir) & '".')
_WinAPI_ShellSetLocalizedName($sDir, $sDll, 6000)
MsgBox(0x00040040, '', 'Press OK to remove localized name.')
_WinAPI_ShellRemoveLocalizedName($sDir)
MsgBox(0x00040040, '', 'Press OK to exit.')

DirRemove($sDir, 1)