函数参考

_WinHttpSetOption

设置互联网选项

#Include <WinHttp.au3>
_WinHttpSetOption($hInternet, $iOption, $vSetting [, $iSize = Default ])

参数

$hInternet 需要设置数据的句柄.
$iOption 包含要设置的互联网选项的整数值.
$vSetting 包含需要设置的字符串值.
$iSize [可选参数] $vSetting 的大小, 当 $vSetting 为一个指向内存区块的指针时需要.

返回值

成功: 返回 1.
失败: 返回 0 并设置 @error:
1 - 无效网络选项
2 - 大小选项需要进行设置
3 - 值的数据类型与选项不匹配
4 - DllCall 失败

注意/说明

None.

相关

_WinHttpQueryOption

详情参考

http://msdn.microsoft.com/en-us/library/aa384114(VS.85).aspx

示例/演示


#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

#include "WinHttp.au3"

Opt("MustDeclareVars", 1)

; 初始化并获取会话句柄
Global $hOpen = _WinHttpOpen()

; 设置用户代理字符串
_WinHttpSetOption($hOpen, $WINHTTP_OPTION_USER_AGENT, "Mozilla/5.0 (Windows; U; Windows NT 6.1; ru; rv:1.9.2.3) Gecko/20100401 Firefox/4.0 (.NET CLR 3.5.30729)")

; 获取连接句柄
Global $hConnect = _WinHttpConnect($hOpen, "google.com")

; 指明请求:
Global $hRequest = _WinHttpOpenRequest($hConnect)

; 发送请求
_WinHttpSendRequest($hRequest)

; 等待响应
_WinHttpReceiveResponse($hRequest)

Global $sHeader
; 如果数据有效...
If _WinHttpQueryDataAvailable($hRequest) Then $sHeader = _WinHttpQueryHeaders($hRequest) ; ...获取完整头部

; 清理
_WinHttpCloseHandle($hRequest)
_WinHttpCloseHandle($hConnect)
_WinHttpCloseHandle($hOpen)

; 显示获取的头部
ConsoleWrite($sHeader & @CRLF)